The DOCUMENT Procedure

Example 3: Managing Entries

Procedure features:

PROC DOCUMENT statement option:

NAME=

DIR statement

LIST statement option:

LEVELS=

NOTE statement

OBANOTE statement

OBBNOTE statement

OBFOOTN statement

OBPAGE statement

OBSTITLE statement

OBTITLE statement

REPLAY statement

ODS destinations:

DOCUMENT

HTML

LISTING

Procedure output:

PROC CONTENTS

Program Description

This example shows you how to do these tasks:

generate PROC CONTENTS output to the DOCUMENT destination
change the title and footnote of the output
add object footer and object heading notes to the output
change the subtitle of the output
add a note to the document
add a page break to the output

Program

options nodate pageno=1;

ods listing close;
ods document name=class;

title 'Title Specified by the Global TITLE Statement';
footnote 'Footnote Specified by the Global FOOTNOTE Statement';

proc contents data=sashelp.class; 
run;

ods document close;
ods listing;

proc document name=class;
   list /levels=all;
run;
   dir \Contents#1\DataSet#1;
run;
   obtitle Attributes#1 'Title Specified by the OBTITLE Statement'; 
run; 
quit;

proc document name=class;
   dir \Contents#1\DataSet#1;
run;
   obbnote Attributes#1 'Object Heading Note Specified by the OBBNOTE Statement'; 
run;
quit;

proc document name=class;
   dir \Contents#1\DataSet#1;
run;
   obfootn Variables#1 'Change the Global Footnote with the OBFOOTN Statement'; 
run;
quit;

proc document name=class;
   dir \Contents#1\DataSet#1; 
run;
   obanote Attributes#1 'Object Footer Note Specified by the OBANOTE Statement'; 
run;
quit;

proc document name=class;
   dir \Contents#1\DataSet#1;
run; 
   obstitle Attributes#1 'Subtitle Specified by the OBSTITLE Statement';
run;
quit;

proc document name=class;
   note addnote 'Note added to the document';
   list /levels=all;
 run;
 quit;

ods html file='your_file.html' style=d3d;
proc document name=class;
   obpage \Contents#1\DataSet#1\Variables#1;
   replay;
run;
quit;

ods _all_ close;

Output

Global Title, Global Footnote, Subtitle, Object Heading Note, Object Footer Note, and Note

[Global Title, Global Footnote, Subtitle, Object Heading Note, Object Footer Note, and Note]

Top of Page