Customized PDF Output
To quickly change the look of your PDF output, specify
the STYLE=, CONTENTS=, and PDFTOC= options in the ODS PDF statement.
The STYLE= option with the Science style specified tells ODS to use
the Science style for all PDF output. The CONTENTS= option with YES
specified creates a table of contents for your PDF file. The PDFTOC=
option with 2 specified expands the table of contents to two levels.
options nodate nonumber orientation=portrait;
proc sort data=sashelp.prdsale out=prdsale;
by Country;
run;
ods pdf file='your-file-path/PDFPrdsaleCustom.pdf' contents=yes pdftoc=2 style=Science;
title 'Actual Product Sales';
title2 '(millions of dollars)';
proc tabulate data=prdsale style=[fontweight=bold];
class region division prodtype / style=[textalign=center];
classlev region division prodtype / style=[textalign=left];
var actual / style=[fontsize=3];
keyword all sum;
keylabel all='Total';
table (region all)*(division all*[style=[backgroundcolor=yellow]]),
(prodtype all)*(actual*f=dollar10.) /
style=[bordercolor=blue] style=[fontstyle=italic]];
run;
title;
title2;
proc univariate data=prdsale;
by Country;
var actual;
run;
ods pdf close;
