NOTALPHA Function

Searches a character string for a nonalphabetic character, and returns the first position at which the character is found.

Category: Character
Restriction: I18N Level 2 functions are designed for use with SBCS, DBCS, and MBCS (UTF8).

Syntax

NOTALPHA(string <,start> )

Required Argument

string

is the character constant, variable, or expression to search.

Optional Argument

start

is an optional numeric constant, variable, or expression with an integer value that specifies the position at which the search should start and the direction in which to search.

Details

The results of the NOTALPHA function depend directly on the translation table that is in effect (see TRANTAB= System Option in SAS National Language Support (NLS): Reference Guide) and indirectly on the ENCODING and the LOCALE system options.
The NOTALPHA function searches a string for the first occurrence of any character that is not an uppercase or lowercase letter. If such a character is found, NOTALPHA returns the position in the string of that character. If no such character is found, NOTALPHA returns a value of 0.
If you use only one argument, NOTALPHA begins the search at the beginning of the string. If you use two arguments, the absolute value of the second argument, start, specifies the position at which to begin the search. The direction in which to search is determined in the following way:
  • If the value of start is positive, the search proceeds to the right.
  • If the value of start is negative, the search proceeds to the left.
  • If the value of start is less than the negative length of the string, the search begins at the end of the string.
NOTALPHA returns a value of zero when one of the following is true:
  • The character that you are searching for is not found.
  • The value of start is greater than the length of the string.
  • The value of start = 0.

Comparisons

The NOTALPHA function searches a character string for a nonalphabetic character. The ANYALPHA function searches a character string for an alphabetic character.

Examples

Example 1: Searching a String for Nonalphabetic Characters

The following example uses the NOTALPHA function to search a string from left to right for nonalphabetic characters.
data _null_;    
   string='Next = _n_ + 12E3;';  
   j=0;  
   do until(j=0);  
      j=notalpha(string,j+1);  
      if j=0 then put +3 "That's all";  
      else do;          
         c=substr(string,j,1);  
         put +3 j= c=;  
      end; 
   end;
run;
The following lines are written to the SAS log:
   j=5 c= 
   j=6 c==
   j=7 c= 
   j=8 c=_
   j=10 c=_
   j=11 c= 
   j=12 c=+
   j=13 c= 
   j=14 c=1
   j=15 c=2
   j=17 c=3
   j=18 c=;
   That's all

Example 2: Identifying Control Characters by Using the NOTALPHA Function

You can execute the following program to show the control characters that are identified by the NOTALPHA function.
data test; 
do dec=0 to 255;
   byte=byte(dec);
   hex=put(dec,hex2.);
   notalpha=notalpha(byte);
   output;
 end;
 proc print data=test;
 run;

See Also

Functions: