Example 14.1 Chemical Equilibrium

The following example is used in many test libraries for nonlinear programming. It appeared originally in Bracken and McCormick (1968).

The problem is to determine the composition of a mixture of various chemicals that satisfy the mixture’s chemical equilibrium state. The second law of thermodynamics implies that at a constant temperature and pressure, a mixture of chemicals satisfies its chemical equilibrium state when the free energy of the mixture is reduced to a minimum. Therefore, the composition of the chemicals satisfying its chemical equilibrium state can be found by minimizing the free energy of the mixture.

The following notation is used in this problem:

The constraints for the mixture are as follows. Each of the compounds must have a nonnegative number of moles.

There is a mass balance relationship for each element. Each relation is given by a linear equality constraint.

The objective function is the total free energy of the mixture.

where

and is the model standard free energy function for the th compound. The value of is found in existing tables. is the total pressure in atmospheres.

The problem is to determine the parameters that minimize the objective function subject to the nonnegativity and linear balance constraints. To illustrate this, consider the following situation. Determine the equilibrium composition of compound at temperature and pressure . The following table gives a summary of the information necessary to solve the problem.

The following statements solve the minimization problem:

   proc iml;
      c = { -6.089 -17.164 -34.054  -5.914 -24.721
            -14.986 -24.100 -10.708 -26.662 -22.179 };
      start F_BRACK(x) global(c);
         s = x[+];
         f = sum(x # (c + log(x / s)));
         return(f);
      finish F_BRACK;

      con = { .  .  .  .  .  .  .  .  .  .    .   .  ,
              .  .  .  .  .  .  .  .  .  .    .   .  ,
              1. 2. 2. .  .  1. .  .  .  1.   0.  2. ,
              .  .  .  1. 2. 1. 1. .  .  .    0.  1. ,
              .  .  1. .  .  .  1. 1. 2. 1.   0.  1. };
      con[1,1:10] = 1.e-6;

      x0 = j(1,10, .1);
      optn = {0 3};

      title 'NLPTR subroutine: No Derivatives';
      call nlptr(xres,rc,"F_BRACK",x0,optn,con);

The F_BRACK module specifies the objective function, . The matrix CON specifies the constraints. The first row gives the lower bound for each parameter, and to prevent the evaluation of the function for values of that are too small, the lower bounds are set here to 1E6. The following three rows contain the three linear equality constraints.

The starting point, which must be given to specify the number of parameters, is represented by X0. The first element of the OPTN vector specifies a minimization problem, and the second element specifies the amount of printed output.

The CALL NLPTR statement runs trust-region minimization. In this case, since no analytic derivatives are specified, the F_BRACK module is used to generate finite-difference approximations for the gradient vector and Hessian matrix.

The output is shown in the following figures. The iteration history does not show any problems.

The output lists the optimal parameters with the gradient.

The three equality constraints are satisfied at the solution.

The Lagrange multipliers and the projected gradient are also printed. The elements of the projected gradient must be small to satisfy a first-order optimality condition.