| The HPFARIMASPEC Procedure |
Example 3.1 Some HPFARIMASPEC Syntax Illustrations
The following statements illustrate the PROC HPFARIMASPEC syntax for some of the commonly needed modeling activities. Suppose that a variety of ARIMA models are to be fit to a data set that contains a sales series as the forecast variable and several promotional events as predictor series. In all these cases the model repository is kept the same, sasuser.arima, and the models are named as model1, model2, and so on, to ensure uniqueness. Note that in a given repository, the models must have unique names. The symbols for the forecast and input variables are sales and promo1, promo2, and so on, respectively.
/* Two transfer functions */
proc hpfarimaspec repository=work.arima
name=model1;
forecast symbol=sales transform=log
q=(1)(12) dif=(1,12) noint;
input symbol=promo1 dif=(1, 12) den=2;
input symbol=promo2 num=2 delay=3;
run;
/* Box-Cox transform and Estimation Method=ML */
proc hpfarimaspec repository=work.arima
name=model2;
forecast symbol=sales transform=BoxCox(0.8) p=2;
estimate method=ml;
run;
/* suppress parameter estimation: in this */
/* case all the parameters must be specified */
proc hpfarimaspec repository=work.arima
name=model3;
forecast symbol=sales transform=log
p=2 ar=0.1 0.8 mu=3.5;
estimate noest method=ml;
run;
/* Supply starting values for the parameters */
proc hpfarimaspec repository=work.arima
name=model4;
forecast symbol=sales transform=log
p=2 ar=0.1 0.8 mu=3.5;
input symbol=promo1
den=1 dc=0.1 nz=-1.5;
run;
/* Create a generic seasonal Airline model with one input
that is applicable for different season lengths */
proc hpfarimaspec repository=work.arima
name=model5
label="Generic Airline Model with One Input";
forecast symbol=Y q=(1)(1)s dif=(1, s) noint
transform= log;
input symbol=X dif=(1, s);
run;
