Create the Annotate data set. The HTML variable is used to define the linking information for each square. Because the GSLIDE procedures that generate the target output use NAME= to ensure the output files are named green.gif, red.gif, blue.gif, and gray.gif, strings that reference those names are assigned to the HTML variable for the appropriate observation in the data. For the final observation, the HTML variable's value is set to a null string; otherwise it would retain the last assigned value, which is href=gray.gif. In that case, the graph's background area would be defined as a hot zone that links to file gray.gif. For a description of the other functions and variables used in the Annotate data set, see Storing Annotate Graphics.

/* create the Annotate data set */
data squares;
     length function style color $ 8
            html text $ 15;
     xsys="3"; ysys="3";

        /* draw the green square */
     color="green";
     function="move"; x=10; y=65; output;
     function="bar";  x=30; y=95; style="solid";
        html="href=green.gif"; output;

        /* label green square */
     function="label"; x=10; y=63; position="6";
        style="swissb"; size=2; text="Green"; output;

        /* draw the red square */
     color="red";
     function="move"; x=60; y=65; output;
     function="bar";  x=80; y=95;
        html="href=red.gif"; output;

        /* label red square */
     function="label"; x=60; y=63; position="6";
        style="swissb"; size=2; text="Red"; output;

        /* draw the blue square */
     color="blue";
     function="move"; x=10; y=15; output;
     function="bar";  x=30; y=45;
        html="href=blue.gif"; output;

        /* label blue square */
     function="label"; x=10; y=12; position="6";
        style="swissb"; size=2; text="Blue"; output;

        /* draw the gray square */
     color="gray";
     function="move"; x=60; y=15; output;
     function="bar";  x=80; y=45;
        html="href=gray.gif"; output;

        /* label gray square and add a footnote */
     function="label"; x=60; y=12; position="6";
        style="swissb"; size=2; text="Gray"; output;

        /* draw a blue frame */
     function="frame"; color="blue"; style="empty";
        /* set null link for background area in frame */
        html=""; output;
run;