The GPLOT Procedure

Example 3: Adding a Right Vertical Axis

Procedure features:

BUBBLE statement options:

	VAXIS=
	HAXIS=
	HMINOR=
	VMINOR=
	BLABEL

Other features:

AXIS statement

FORMAT statement

GOPTIONS statement option:

BORDER

Sample library member:

GPLAXIS1

[Bubble plot with right vertical axis]

This example modifies Labeling and Sizing Plot Bubbles to show how a BUBBLE2 statement generates a right vertical axis that displays the values of the vertical coordinates in a different scale from the scale that is used for the left vertical axis. Salary values are scaled by dollars on the left vertical axis and by yen on the right vertical axis.

BUBBLE and BUBBLE2 statement options control the appearance of the graph. In particular, the VAXIS options calibrate the axes so that the data points are identical and only one set of bubbles appears.

Note: If the data points are not identical, two sets of bubbles are displayed. [cautionend]

goptions reset=all border;

data jobs2;
   set jobs;
   yen=dollars*125;
run;

title1 "Member Profile";
title2 "Salaries and Number of Member Engineers";
footnote j=r "GPLAXIS1 ";

axis1 offset=(5,5);

proc gplot data=jobs2;
   format dollars dollar7. num yen comma9.0;
   bubble dollars*eng=num / haxis=axis1
                            vaxis=10000 to 40000 by 10000
                            hminor=0
                            vminor=1
                            blabel;

   bubble2 yen*eng=num / vaxis=1250000 to 5000000 by 1250000
                         vminor=1;
run;
quit;

Top of Page