Model files enable you to save models that are specified in a PROC MODEL step to a SAS library file. Model files store the SAS programming statements and variable declarations that constitute a model, and they make those statements and declarations available for use in subsequent PROC MODEL steps. Typically you specify the OUTMODEL= option in one PROC MODEL step to save a model specification to a model file, and later you specify the MODEL= option in one or more other PROC MODEL steps to read one or more model files. For more information, see the section Storing Programs in Model Files.
Model files can help organize modeling efforts when many statements are required to specify, estimate, and simulate models. For example, in the supply and demand model analyzed previously, the following statements specify the system of equations once and save them to the model file SUPDEM:
proc model outmodel=supdem;
endogenous eegp eec;
exogenous exvus cciutc;
parameters a1 a2 b1 b2 b3 ;
label eegp = 'Gasoline Retail Price'
eec = 'Energy Consumption'
cciutc = 'Consumer Debt';
/* -------- Supply equation ------------- */
eq.supply = eec - (a1 + a2 * eegp );
/* -------- Demand equation ------------- */
eq.demand = eec - (b1 + b2 * eegp + b3 * cciutc);
quit;
When the model has been defined and saved, its parameters can be estimated in a separate PROC MODEL step. The following estimation step defines the instruments LAGEEGP and LAG2EEGP (which do not appear in the supply and demand model equations) and performs the three-stage least squares estimation:
proc model data=sashelp.citimon model=supdem outmodel=supdem; /* -------- Instrumental variables ------ */ lageegp = lag(eegp); lag2eegp=lag2(eegp); /* -------- Estimate parameters --------- */ instruments _EXOG_ lageegp lag2eegp; fit supply demand / n3sls; quit;
Finally, the following statements use the supply and demand model together with its parameter estimates to solve for equilibrium prices and quantities:
proc model data=sashelp.citimon(where=(eec ne .)) model=supdem; solve eegp eec / out=equilib; quit;